How to rotate the curve but not the axes?

p = Plot[Interpolation[Reverse /@ data, x, InterpolationOrder -> 2], {x, 0, 55}, 
         Epilog -> {Red, PointSize[.01], Point[Reverse /@ data]}, Filling -> Axis]

You can post-process p to rotate the graphics primitives:

Show[Normal[p] /. prim : _Line | _Point | _Polygon :> 
   GeometricTransformation[prim, RotationTransform[Pi/2]], 
 PlotRange -> All, AspectRatio -> GoldenRatio]

This is pretty neat:

data = {{0, 5}, {1.9, 7.5}, {0, 12}, {-5, 15.5}, {-1.2, 33.4}};
iFun = Interpolation[Reverse[data, 2], InterpolationOrder -> 2];
ParametricPlot[Cross[{x, iFun[x]}], {x, 0, 55}, AspectRatio -> GoldenRatio, 
               Epilog -> {Directive[Red, PointSize[.01]],
                          Point[Cross /@ Reverse[data, 2]]}]

I'll leave fiddling with the ticks up to you.

data = {{0, 5}, {1.9, 7.5}, {0, 12}, {-5, 15.5}, {-1.2, 33.4}};
plot = Plot[
   Interpolation[Reverse /@ data, x, InterpolationOrder -> 2], {x, 0, 
    55}, Epilog -> {Red, PointSize[.01], Point[Reverse /@ data]}];


Graphics[
   Rotate[{#, Epilog /. {##2}}, Pi/2, {0, 0}], 
   AspectRatio -> GoldenRatio, Axes -> True
] & @@ plot