The symbolic result does not give a proper answer when inputs are specified

$Version

(* "12.1.1 for Mac OS X x86 (64-bit) (June 19, 2020)" *)

Clear["Global`*"]

F[m_, k_, i_, j_] := (-1)^(m + k)/(m!*k!)*2^m*Binomial[m, i]*Binomial[k + 1, j]

sum[i_, j_] = 
 Sum[F[m, k, i, j], {m, 0, Infinity}, {k, 0, Infinity}] // FullSimplify

(* -2^i E^(-3 + I i π) (-1 + j) Binomial[0, i] Binomial[1, 
  j] (Gamma[1 - i] + i Gamma[-i, -2]) (E + 
   E^(I j π) (Gamma[2 - j] + E (-1 + j) Subfactorial[-j])) *)

sum[2, 2]

Define the sum as a Limit

sum2[i_, j_] := Limit[sum[m, n], {m, n} -> {i, j}]

Then

sum2[2, 2]

(* -(1/E^3) *)

Comparing with direct evaluation (this is quite slow)

And @@ Flatten[
  Table[Sum[F[m, k, i, j], {m, 0, Infinity}, {k, 0, Infinity}] == 
    sum2[i, j], {i, 0, 5}, {j, 0, 5}]]

(* True *)

You can get the sum for 169 values of $(i,j)$ by taking the limit of the what you get from Sum:

expr = FullSimplify[Sum[F[m, k, i, j], {m, 0, ∞}, {k, 0, ∞}]];
ss2[iv_, jv_] := ss2[iv, jv] = Limit[expr, {i, j} -> {iv, jv}]
mat = Table[ss2[iv, jv], {iv, 0, 12}, {jv, 0, 12}];

From these values FindSequenceFunction can suggest a closed form that works on integers:

FindSequenceFunction[#, j + 1] & /@ (mat E^3)

{((-1)^(1 + j) (-1 + j))/(2 Pochhammer[3, -2 + j]),
 ((-1)^(2 + j) (-1 + j))/Pochhammer[3, -2 + j],
 ((-1)^(1 + j) (-1 + j))/Pochhammer[3, -2 + j],
 -((2 (-1)^(1 + j) (-1 + j))/(3 Pochhammer[3, -2 + j])),
 ((-1)^(1 + j) (-1 + j))/(3 Pochhammer[3, -2 + j]),
 -((2 (-1)^(1 + j) (-1 + j))/(15 Pochhammer[3, -2 + j])),
 ..........}

which suggest a closed form except for a factor depending on i:

MapThread[FindSequenceFunction[#2, j + 1]/(((-1)^(# + j) (1 - j))/Pochhammer[3, j - 2]) &, {Range[0, 12], (mat E^3)}] // Simplify
(* {1/2, 1, 1, 2/3, 1/3, 2/15, 2/45, 4/315, 1/315, 2/2835, 2/14175, 4/155925, 2/467775} *)

FindSequenceFunction recognize the factor:

FindSequenceFunction[{1/2, 1, 1, 2/3, 1/3, 2/15, 2/45, 4/315, 1/315, 2/2835, 2/14175, 4/155925, 2/467775}, # + 1]
(* 2^(-1 + #1)/Pochhammer[1, #1] *)

Combining these we get:

2^(-1 + #1)/Pochhammer[1, #1] ((-1)^(# + j) (1 - j))/Pochhammer[3, -2 + j] &[i] // FullSimplify

$$\frac{2^i (1-j)e^{-3}}{i! j! (-1)^{i+j}}$$

I tried to Plot3D it.

Plot3D[Evaluate@ Sum[(-1)^(m + k)/(m!*k!)*2^m*Binomial[m, i]*Binomial[k + 1, j], {m,  0, Infinity}, {k, 0, Infinity}], {i, -5, 5}, {j, -5, 5}, PlotPoints -> 20, PlotRange -> All]

Looks like a lot of discontinuity.

But there are some points return values.

/. {i -> 51/10, j -> 45/10}

-(1/(E^3))(-((544 (-2)^(1/10) E Binomial[0, 51/10] Gamma[-(51/10)])/(
                15 π)) + (
            73984 I (-2)^(1/10) Binomial[0, 51/10] Gamma[-(51/10)])/(
            2205 Sqrt[π]) - (
            17408 (-1)^(3/5) 2^(1/10) Binomial[0, 51/10] Gamma[-(51/10)])/(
            1225 Sqrt[π]) + (
            544 (-2)^(1/10) E Binomial[0, 51/10] Gamma[-(51/10), -2])/(
            15 π) - (
            73984 I (-2)^(1/10) Binomial[0, 51/10] Gamma[-(51/10), -2])/(
            2205 Sqrt[π]) + (
            17408 (-1)^(3/5) 2^(1/10) Binomial[0, 51/10] Gamma[-(51/10), -2])/(
            1225 Sqrt[π]) - (
            4624 I (-2)^(1/10)
                    Binomial[0, 51/10] Gamma[-(51/10)] Gamma[-(7/2), -1])/(
            21 π) + (
            3264 (-1)^(3/5) 2^(1/10)
                    Binomial[0, 51/10] Gamma[-(51/10)] Gamma[-(7/2), -1])/(
            35 π) + (
            4624 I (-2)^(1/10)
                    Binomial[0, 51/10] Gamma[-(51/10), -2] Gamma[-(7/2), -1])/(
            21 π) - (
            3264 (-1)^(3/5) 2^(1/10)
                    Binomial[0, 51/10] Gamma[-(51/10), -2] Gamma[-(7/2), -1])/(
            35 π))