Integrating a BesselJ integrand to obtain the same result as Maple 16

Mathematica can do it, but need to use the HypergeometricPFQ form, as follows. For some reason, Mathematica can't do it in BesselJ. May be a report should be send to [email protected]

First to show that the HypergeometricPFQ form is equivalent to the BesselJ form:

 bad = BesselJ[1, x*Exp[I*Pi/4]]*BesselJ[1, x*Exp[-I*Pi/4]];
 good = 1/4 x^2 HypergeometricPFQ[{},{2},-1/4 I x^2] HypergeometricPFQ[{},{2},1/4 I x^2]
 FullSimplify[bad - good]
 (* 0 *)

Now the integral works, and gives the result shown by Maple. So Maple is correct :)

 WL = Integrate[y*Integrate[1/x*good, {x, 0, y}], {y, 0, r}]
 (* -(1/32) I r^2 Sqrt[-r^4]  HypergeometricPFQ[{1/2}, {3/2, 3/2, 2, 2}, r^4/64] *)

To verify the above is the same as Maple's:

maple = 1/32*r^4*HypergeometricPFQ[{1/2}, {3/2, 3/2, 2, 2}, 1/64 r^4];
Grid[Join[{{"r", "WL", "Maple"}}, 
  N@Table[{i, WL /. r -> i, maple /. r -> i}, {i, 0, 10, 1}]]]

It looks like the trick making the integration possible is just a change of variable Exp[-I Pi/4] x -> z. Defining :

g[z_, y_] = Exp[-I Pi/4] y/z BesselJ[1, z] BesselJ[1, I z]

gives

Integrate[Integrate[ Exp[I Pi/4] g[z, y], {z, 0, Exp[-I Pi/4] y}], {y, 0, r}]
(* 1/32 r^4 HypergeometricPFQ[{1/2}, {3/2, 3/2, 2, 2}, r^4/64] *)

As it turns out, although Mathematica is unable to deal with the integral as it stands, using the Kelvin functions yields an answer equivalent to the one returned by Maple.

In particular,

Integrate[(y/x) (KelvinBer[1, x]^2 + KelvinBei[1, x]^2), {y, 0, r}, {x, 0, y}]
   1/32 r^4 HypergeometricPFQ[{1/2}, {3/2, 3/2, 2, 2}, r^4/64]

where I used one of the defining relations between Kelvin and Bessel functions given in the DLMF.