Can I solve a certain equation?

Manipulate[
 Show[
  ContourPlot[
   (1 + x)^(2/m) - (1 - x)^(2/m) - (1 - x^2)^(1/m),
   {x, -.1, 1.1}, {m, .1, 5}, Contours -> {0}],
  pt = {x /. FindRoot[
      (1 + x)^(2/m) - (1 - x)^(2/m) - (1 - x^2)^(1/m),
      {x, m/5}],
    m};
  Graphics[{
    Text[ToString[Round[pt, .001]], pt, {-1.25, 0}],
    Red, AbsolutePointSize[6], Point[pt]}]],
 {{m, 1}, .1, 5, .01, Appearance -> "Labeled"}]

This problem is solvable analytically, although we use Mathematica for some of the algebra. To begin, write the initial expression as

(1 + x)^(2/m) - (1 - x)^(2/m) - (1 - x^2)^(1/m);

and divide through by the third term.

Expand[-%/%[[3]]] /. (1 - x^2)^(-1/m) -> (1 - x)^(-1/m) (1 + x)^(-1/m)
(* -1 - (1 - x)^(1/m) (1 + x)^(-1/m) + (1 - x)^(-1/m) (1 + x)^(1/m) *)

Replacing ((1 + x)/(1 - x))^(1/m) by z casts the expression into the form

z - 1 - 1/z

which can be solved by

zsol = Solve[z - 1 - 1/z == 0, z]
(* {{z -> 1/2 (1 - Sqrt[5])}, {z -> 1/2 (1 + Sqrt[5])}} *)

Choose the second solution to obtain real x.

zsol[[2, 1]] /. z -> ((1 + x)/(1 - x))^(1/m) /. Rule -> Equal;
Solve[%, x][[1, 1]]
(* x -> (-1 + (1/2 + Sqrt[5]/2)^m)/(1 + (1/2 + Sqrt[5]/2)^m) *)

For comparison with the numerical solution by Bob Hanlon,

%[[2]] /. m -> 1 // N
(* 0.236068 *)