Are plotting markers with inscribed letters possible?

Update: Using some of the ideas in the linked Q/As, you can get a finer customization of your markers:

Jw1e1 = {{16, 832}, {32, 3150}, {64, 12237}, {128, 48212}};
Jw1e3 = {{16, 826}, {32, 3127}, {64, 12145}, {128, 47851}};
(* second list modified so that the two plots do not overlap*)
lists = {Jw1e1, {1, .1} # & /@ Jw1e3} ;
markerDisk = Graphics[{Opacity[.6],
 Dynamic@EdgeForm[{clr = CurrentValue["Color"], Thick}],
 Dynamic[FaceForm[{Opacity[1], Lighter[clr, .3]}]], Disk[], Opacity[1],
 Style[Text[#], White, Bold, 16]}, ImagePadding -> Scaled[.01]] &;

ListLogPlot[lists, Joined -> True, ImageSize -> 500,
 PlotRangeClipping -> False, ImagePadding -> 35,
 PlotMarkers :> ({markerDisk[#], 0.15} & /@ {A, B})]]

---

From Docs > PlotMarkers > Details:

mrkr = Graphics[{Red, Thick, Circle[], Style[Text[H], Red, Bold, 24]}]; 
ListLogPlot[Jw1e1, PlotMarkers -> {mrkr, .2}, Frame -> True]

Related Q/As

Why doesn' t PlotMarker option None return no PlotMarkers?

ListPlot with plotmarkers determined by point

You were nearly there:

Jw1e1 = {{16, 832}, {32, 3150}, {64, 12237}, {128, 48212}};

J1 = ListLogPlot[Jw1e1, 

  PlotMarkers -> (Style[Framed[H, RoundingRadius -> 20], Red]), 

  Frame -> True]

The nice thing here is that you can play around with RoundingRadius and that longer/larger text markers will be properly framed as well.

J1 = ListLogPlot[Jw1e1, 

  PlotMarkers -> (Style[

     Framed["Longer than strictly necessary", RoundingRadius -> 20], 

     Red]), Frame -> True]

Driving it home:

J1 = ListLogPlot[Jw1e1, 

  PlotMarkers -> 

   Framed[Style["Larger than \n strictly necessary", Large, Red], 

    RoundingRadius -> 20], Frame -> True]